Bruker Topspin 3 pulse program:
REAPDOR

Home and Applets > Pulse Sequence > Bruker Topspin 3 Pulse Program

Rotational Echo Adiabatic Passage DOuble Resonance, Bruker Topspin 3 pulse program

topspin3 REAPDOR pulse sequence

The first signal amplitude is provided by two-rotor-period REAPDOR experiment.

reapdor

;reapdor
;
; REAPDOR experiment 
; single pulse excitation, no decoupling
; optional saturation pulse train on observe nucleus
;
;Avance III version
;parameters:
;p1 : F1  90 degree pulse
;p2 : F1 180 degree pulse
;p12 : = d31/3 F2 recoupling pulse of duration 1/3 of rotor period
;d1 : recycle delay
;d20 : delay in saturation pulse train
;d31 : =1s/cnst31, 1 rotor period
;ns : 4*n 
;pl1 : F1 power level (90/180)
;pl2 : F2 power level (adiabatic pulse)
;l0 : =0, must be even for rotor sync
;l20 : number of pulses in saturation pulse train, 0 if undesired
;cnst31 : spinning frequency
;FnMODE: QF
;
;
;$CLASS=Solids
;$DIM=pseudo 2D
;$TYPE=direct excitation
;$SUBTYPE=
;$COMMENT=REAPDOR experiment, single pulse excitation


define delay del25      ;calculate sync. delays
"del25=(0.25s/cnst31)-(p1/2)"
define delay del26
"del26=(0.25s/cnst31)-(p2/2)"
define delay del27
"del27=(0.25s/cnst31)-(p12/2)"
define delay del28
"del28=(0.25s/cnst31)-de"
"d31=1s/cnst31"
"acqt0=0"

1 ze                    ;accumulate into an empty memory
  d31
2 10m
saturate, d20           ;optional saturation recovery
  (p1 pl1 ph1):f1
  lo to saturate times l20
  d1
#include <aq_prot.incl>
                        ;allows max. 50 msec acquisition time, supervisor
                        ;may change  to max. 1s at less than 5 % duty cycle
                        ;and reduced decoupling field
#include <rot_prot.incl>
                        ;protect against misset cnst31, must be >1000
  2u rpp8
  2u rpp9
  (p1 pl1 ph2):f1
  del25
3 del26 
  (p2 pl1 ph8^):f1
  del26
  lo to 3 times l0
  del26 
  (p2 pl1 ph3):f1
  del26 	
  del27
  (p12 pl2 ph5):f2      ;adiabatic pulse
  del27
4 del26
  (p2 pl1 ph9^):f1
  del26
  lo to 4 times l0
  del26
  (p2 pl1 ph4):f1
  del26
  del28
  go=2 ph31
  10m mc #0 to 2 F1QF(1m iu0 & 1m iu0)
HaltAcqu, 1m            ;jump address for protection files
exit

ph1= 0
ph2= 0 2 1 3
ph3= 0 2 1 3
ph4= 0 2 1 3
ph5= 0
ph8= 0 1 0 1 1 0 1 0
ph9= 0 1 0 1 1 0 1 0
ph31=0 2 1 3

reapdori

;reapdori
;
; REAPDOR experiment 
; single pulse excitation, no decoupling
; optional saturation pulse train on observe nucleus
; uses interleaved acquisition for FIDs with and w/o recoupling pulse;
;
;Avance III version
;
;parameters:
;p1 : F1  90 degree pulse
;p2 : F1 180 degree pulse
;p12 : = d31/3 F2 adiabatic pulse of duration 1/3 of rotor period
;d1 : recycle delay
;d20 : delay in saturation pulse train
;d31 : =1s/cnst31, 1 rotor period
;ns : 4*n 
;pl1 : F1 power level (90/180)
;pl2 : F2 power level (adiabatic pulse)
;pl12 : =0W (no adiabatic pulse)
;l0 : =2, must be even for rotor sync
;l20 : number of pulses in saturation pulse train, 0 if undesired
;cnst31 : spinning frequency
;FnMODE: undefined
;
;
;$CLASS=Solids
;$DIM=pseudo 2D
;$TYPE=direct excitation
;$SUBTYPE=
;$COMMENT=REAPDOR experiment, single pulse excitation, interleaved acquisition of S and S0 signals


define loopcounter nfid
"nfid=td1/2"
define delay del25      ;calculate sync. delays
"del25=(0.25s/cnst31)-(p1/2)"
define delay del26
"del26=(0.25s/cnst31)-(p2/2)"
define delay del27
"del27=(0.25s/cnst31)-(p12/2)"
define delay del28
"del28=(0.25s/cnst31)-de"
"d31=1s/cnst31"
"acqt0=0"

1 ze                    ;accumulate into an empty memory
  d31
2 10m
saturate, d20           ;optional saturation recovery
  (p1 pl1 ph1):f1
  lo to saturate times l20
  d1
#include <aq_prot.incl>
                        ;allows max. 50 msec acquisition time, supervisor
                        ;may change  to max. 1s at less than 5 % duty cycle
                        ;and reduced decoupling field
#include <rot_prot.incl>
                        ;protect against misset cnst31, must be >1000
  2u rpp8
  2u rpp9
  (p1 pl1 ph2):f1
  del25
3 del26
  (p2 pl1 ph8^):f1
  del26
  lo to 3 times l0
  del26 
  (p2 pl1 ph3):f1
  del26
  del27
  (p12 pl2 ph5):f2      ;adiabatic pulse
  del27
4 del26
  (p2 pl1 ph9^):f1
  del26
  lo to 4 times l0
  del26 
  (p2 pl1 ph4):f1
  del26
  del28
  go=2 ph31
  30m wr #0 if #0 zd    ;save data to disk

12 10m
sat, d20                ;optional saturation recovery
  (p1 pl1 ph1):f1
  lo to sat times l20
  d1
  2u rpp8
  2u rpp9
  (p1 pl1 ph2):f1
  del25
13 del26 
  (p2 pl1 ph8^):f1
  del26
  lo to 13 times l0
  del26 
  (p2 pl1 ph3):f1
  del26
  del27
  (p12 pl12 ph5):f2     ;adiabatic pulse
  del27
14 del26
  (p2 pl1 ph9^):f1
  del26
  lo to 14 times l0
  del26 
  (p2 pl1 ph4):f1
  del26
  del28
  go=12 ph31
  30m wr #0 if #0 zd    ;save data to disk
  1m iu0                ;increment REAPDOR loop
  1m iu0                ;twice
  lo to 2 times nfid    ;do td1 experiments
HaltAcqu, 1m            ;jump address for protection files
exit

ph1= 0
ph2= 0 2 1 3
ph3= 0 2 1 3
ph4= 0 2 1 3
ph5= 0
ph8= 0 1 0 1 1 0 1 0
ph9= 0 1 0 1 1 0 1 0
ph31=0 2 1 3

cpreapdor

;cpreapdor (TopSpin 3.0)
;
;REAPDOR experiment
;CP excitation and decoupling
;uses interleaved acquisition for FIDs with and w/o recoupling pulse;
;
;Avance III version
;parameters:
;ns : 8*n
;p3 : proton 90 at power level pl2
;p15 : contact time at pl1 (f1) and sp0 (f2)
;pcpd2 : pulse length in decoupling sequence
;cpdprg2 : cw, tppm (at pl12), 
;p2 : X 180 degree pulse at pl11
;p12 : Y adiabatic pulse at pl3, theory best at Tr/3
;cnst3 : fraction of Tr (rotor period) for calc of p12
;cnst31 : spin rate
;l0 : even integer from zero
;l20 : number of pulses in saturation pulse train, 0 if undesired
;d1 : recycle delay
;d20 : delay in saturation pulse train
;d31 : used to check spin rate
;pl1 : X power level for contact
;pl11 : X power level for 180
;sp0 : proton CP power level
;pl2 : proton 90 power level
;pl12 : proton decoupling power level
;pl3 : Y pulse power level
;pl13 : e.g. used in tppm13
;spnam0 : file name for variable amplitude CP
;FnMODE: QF;
;
;$COMMENT=REAPDOR experiment, cp for excitation, interleaved acquisition of S and S0 signals
;$CLASS=Solids
;$DIM=pseudo 2D
;$TYPE=cross polarisation
;$SUBTYPE=REAPDOR

"p12=(1s*cnst3)/cnst31"
define delay del25     ;calculate sync. delays
"del25=(0.25s/cnst31)"
define delay del26
"del26=(0.25s/cnst31)-(p2/2)"
define delay del27
"del27=(0.25s/cnst31)-(p12/2)"

"d31=1s/cnst31"
"acqt0=0"

1 ze
  d31
2 10m do:f2
saturate, d20          ;optional saturation recovery
  (p3 ph1 pl2):f2
  lo to saturate times l20
  d1
#include <p15_prot.incl>
            ;make sure p15 does not exceed 10 msec
            ;let supervisor change this pulseprogram if 
            ;more is needed
#include <aq_prot.incl>
            ;allows max. 50 msec acquisition time, supervisor
            ;may change  to max. 1s at less than 5 % duty cycle
            ;and reduced decoupling field
#include <rot_prot.incl>
            ;protect against misset cnst31, must be > 1000
  2u rpp9
  2u rpp8
  (p3 ph1 pl2):f2
  (p15 ph2 pl1):f1 (p15:sp0 ph10):f2
  del25 cpds2:f2
3 del26 
  (p2 ph8^ pl11):f1
  del26
  lo to 3 times l0
  del26
  (p2 ph2):f1
  del26
  del27
  (p12 ph4 pl3):f3   ;adiabatic pulse
  del27
4 del26
  (p2 ph9^ pl11):f1
  del26
  lo to 4 times l0
  del26
  (p2 ph2):f1
  del26
  del25
  go=2 ph31
  1m do:f2
  10m mc #0 to 2 F1QF(1m iu0 & 1m iu0)
HaltAcqu, 1m
exit

ph1= 1 3
ph2= 0 0 2 2 1 1 3 3
ph4= 0
ph8= 0 1 0 1 1 0 1 0
ph9= 0 1 0 1 1 0 1 0
ph10= 0
ph31= 0 2 2 0 1 3 3 1

cpreapdori

;cpreapdori (TopSpin 3.0)
;
;REAPDOR experiment
;CP excitation and decoupling
;uses interleaved acquisition for FIDs with and w/o recoupling pulse;
;
;Avance III version
;parameters:
;ns : 8*n
;p3 : proton 90 at power level pl2
;p15 : contact time at pl1 (f1) and sp0 (f2)
;pcpd2 : pulse length in decoupling sequence
;cpdprg2 : cw, tppm (at pl12), 
;p2 : X 180 degree pulse at pl11
;p12 : Y adiabatic pulse at pl3, theory best at Tr/3
;cnst3 : fraction of Tr (rotor period) for calc of p12
;cnst31 : spin rate
;l0 : even integer from zero
;l20 : number of pulses in saturation pulse train, 0 if undesired
;d1 : recycle delay
;d12 : = p12, length of Y pulse
;d20 : delay in saturation pulse train
;d31 : used to check spin rate
;pl1 : X power level for contact
;pl11 : X power level for 180
;sp0 : proton CP power level
;pl2 : proton 90 power level
;pl12 : proton decoupling power level
;pl3 : Y pulse power level
;pl13 : e.g. used in tppm13
;pl22 : =120 dB (no recoupling pulses)
;spnam0 : file name for variable amplitude CP
;FnMODE: QF;
;
;$COMMENT=REAPDOR experiment, cp for excitation, interleaved acquisition of S and S0 signals
;$CLASS=Solids
;$DIM=pseudo 2D
;$TYPE=cross polarisation
;$SUBTYPE=REAPDOR

"plw22=0"               ;make sure reference exp. has no recoupling pulses (TS 3.0)

"d31=1s/cnst31"
"p12=(1s*cnst3)/cnst31"

define delay del25      ;calculate sync. delays
"del25=(0.25s/cnst31)"
define delay del26
"del26=(0.25s/cnst31)-(p2/2)"
define delay del27
"del27=(0.25s/cnst31)-(p12/2)"
define loopcounter nfid
"nfid=td1/2"
"acqt0=0"

1 ze
  d31
2 10m do:f2
saturate, d20          ;optional saturation recovery
  (p3 ph1 pl2):f2
  lo to saturate times l20
  d1
#include <p15_prot.incl>
            ;make sure p15 does not exceed 10 msec
            ;let supervisor change this pulseprogram if
            ;more is needed
#include <aq_prot.incl>
            ;allows max. 50 msec acquisition time, supervisor
            ;may change  to max. 1s at less than 5 % duty cycle
            ;and reduced decoupling field
#include <rot_prot.incl>
            ;protect against misset cnst31, must be > 1000
  2u rpp9
  2u rpp8
  (p3 ph1 pl2):f2
  (p15 ph2 pl1):f1 (p15:sp0 ph10):f2
  del25 cpds2:f2
3 del26 
  (p2 ph8^ pl11):f1
  del26
  lo to 3 times l0
  del26
  (p2 ph2):f1
  del26
  del27
  (p12 ph4 pl3):f3   ;adiabatic pulse
  del27
4 del26
  (p2 ph9^ pl11):f1
  del26
  lo to 4 times l0
  del26
  (p2 ph2):f1
  del26
  del25
  go=2 ph31
  1m do:f2
  30m wr #0 if #0 zd
;
12 10m do:f2 
  d1
  2u rpp9
  2u rpp8
  (p3 ph1 pl2):f2
  (p15 ph2 pl1):f1 (p15:sp0 ph10):f2
  del25  cpds2:f2
13 del26 
  (p2 ph8^ pl11):f1
  del26
  lo to 13 times l0
  del26
  (p2 ph2):f1
  del26
  del27
  (p12 ph4 pl22):f3   ;no adiabatic pulse
  del27
14 del26
  (p2 ph9^ pl11):f1
  del26
  lo to 14 times l0
  del26
  (p2 ph2):f1
  del26
  del25
  go=2 ph31
  1m do:f2
  30m wr #0 if #0 zd
  1m iu0
  1m iu0
  lo to 2 times nfid
HaltAcqu, 1m
exit

ph1= 1 3
ph2= 0 0 2 2 1 1 3 3
ph4= 0
ph8= 0 1 0 1 1 0 1 0
ph9= 0 1 0 1 1 0 1 0
ph10= 0
ph31= 0 2 2 0 1 3 3 1

References

Dataset supporting: Amyloid hydrogen bonding polymorphism evaluated by 15N{17O}REAPDOR solid-state NMR and ultra-high resolution FTICR-MS

Solid-state NMR bibliography for:

Aluminum-27
Antimony-121/123
Arsenic-75
Barium-135/137
Beryllium-9
Bismuth-209
Boron-11
Bromine-79/81
Calcium-43
Cesium-133
Chlorine-35/37
Chromium-53
Cobalt-59
Copper-63/65
Deuterium-2
Gallium-69/71
Germanium-73
Gold-197
Hafnium-177/179
Indium-113/115
Iodine-127
Iridium-191/193
Krypton-83
Lanthanum-139
Lithium-7
Magnesium-25
Manganese-55
Mercury-201
Molybdenum-95/97
Neon-21
Nickel-61
Niobium-93
Nitrogen-14
Osmium-189
Oxygen-17
Palladium-105
Potassium-39/41
Rhenium-185/187
Rubidium-85/87
Ruthenium-99/101
Scandium-45
Sodium-23
Strontium-87
Sulfur-33
Tantalum-181
Titanium-47/49
Vanadium-51
Xenon-131
Zinc-67
Zirconium-91
[Contact me] - Last updated February 21, 2020
Copyright © 2002-2024 pascal-man.com. All rights reserved.