Bruker Topspin 3 pulse program:
REDOR




Home and Applets > Pulse Sequence > Bruker Topsin 3 REDOR Pulse Program

Rotational Echo DOble Resonance, Bruker Topspin 3 pulse program


*** Outline ***


topspin3 REDOR pulse sequence

The first signal amplitude is provided by two-rotor-period REDOR experiment.

redor

;redor
;TS3 / 09.08.2011
;
;checked by SEWE 09.08.2011
;
; REDOR experiment 
; single pulse excitation, no decoupling
; optional saturation pulse train on observe nucleus
;
;
; written by Stefan Steuernagel (031201)
;
;
;Avance III version
;parameters:
;p1 : F1  90 degree pulse
;p2 : F1 180 degree pulse
;p12 : F2 180 degree pulse
;d1 : recycle delay
;d20 : delay in saturation pulse train
;d31 : =1s/cnst31, 1 rotor period
;ns : 16*n 
;pl1 : F1 power level (90/180)
;pl2 : F2 power level (180)
;l0 : =1, must be odd for rotor sync
;l20 : number of pulses in saturation pulse train, 0 if undesired
;cnst31 : spinning frequency
;FnMODE: QF
;
;
;$CLASS=Solids
;$DIM=pseudo 2D
;$TYPE=direct excitation
;$SUBTYPE=
;$COMMENT=REDOR experiment, single pulse excitation


define delay del25		;calculate sync. delays
"del25=(0.25s/cnst31)-(p1/2)"
define delay del26
"del26=(0.25s/cnst31)-(p12/2)"
define delay del27
"del27=(0.25s/cnst31)-(p2/2)"
define delay del28
"del28=(0.25s/cnst31)-de"
"d31=1s/cnst31"
"acqt0=0"

1 ze                    ;accumulate into an empty memory
  d31
2 10m
saturate, d20           ;optional saturation recovery
  (p1 pl1 ph1):f1
  lo to saturate times l20
  d1
#include <aq_prot.incl>
                        ;allows max. 50 msec acquisition time, supervisor
                        ;may change  to max. 1s at less than 5 % duty cycle
                        ;and reduced decoupling field
#include <rot_prot.incl>
                        ;protect against misset cnst31, must be >1000
  2u rpp9
  2u rpp8
  (p1 pl1 ph2):f1
  del25
3 del26 
  (p12 pl2 ph8^):f2	
  del26
  lo to 3 times l0
  del27
  (p2  ph5):f1
  del27
4 del26
  (p12 ph9^):f2	
  del26
  lo to 4 times l0
  del28
  go=2 ph31
  10m mc #0 to 2 F1QF(1m iu0 & 1m iu0)
HaltAcqu, 1m            ;jump address for protection files
exit

ph1= 0
ph2= 0 2 1 3
ph5= 0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3
ph8= 0 1 0 1 1 0 1 0
ph9= 0 1 0 1 1 0 1 0
ph31=0 2 3 1 2 0 1 3

redori

;redori
;TS3 / 09.08.2011
;
;checked by SEWE 09.08.2011
;
; REDOR experiment 
; single pulse excitation, no decoupling
; optional saturation pulse train on observe nucleus
; uses interleaved acquisition for FIDs with and w/o recoupling pulses
;
;
;Avance III
;
;
;parameters:
;pl1 : F1 power level
;pl2 : F2 power level for 180 recoupling pulses
;pl12 : =0W (no recoupling pulses)
;p1 : F1  90 degree pulse
;p2 : F1 180 degree pulse
;p12 : F2 180 degree pulse
;ns : 16*n 
;d1 : recycle delay
;d20 : delay in saturation pulse train
;d31 : =1s/cnst31, 1 rotor period
;l0 : =1, must be odd
;l20 : number of pulses in saturation pulse train, 0 if undesired
;cnst31 : spinning frequency
;FnMODE: undefined
;
;
;$CLASS=Solids
;$DIM=pseudo 2D
;$TYPE=direct excitation
;$SUBTYPE=
;$COMMENT=REDOR experiment, single pulse excitation, interleaved acquisition of S and S0 signals


define loopcounter nfid
"nfid=td1/2"
define delay del25		;calculate sync. delays
"del25=(0.25s/cnst31)-(p1/2)"
define delay del26
"del26=(0.25s/cnst31)-(p12/2)"
define delay del27
"del27=(0.25s/cnst31)-(p2/2)"
define delay del28
"del28=(0.25s/cnst31)-de"
"d31=1s/cnst31"
;cnst11 : to adjust t=0 for acquisition, if digmod = baseopt
"acqt0=0"

1 ze
  d31
2 10m
saturate, d20
  (p1 pl1 ph1):f1
  lo to saturate times l20
  d1
#include <aq_prot.incl>	
                        ;allows max. 50 msec acquisition time, supervisor
                        ;may change  to max. 1s at less than 5 % duty cycle
                        ;and reduced decoupling field
#include <rot_prot.incl>
                        ;protect against misset cnst31, must be >1000
  2u rpp9
  2u rpp8
  (p1 pl1 ph2):f1
  del25
3 del26 
  (p12 pl2 ph8^):f2
  del26
  lo to 3 times l0
  del27
  (p2  ph5):f1
  del27
4 del26
  (p12 ph9^):f2	
  del26
  lo to 4 times l0
  del28
  go=2 ph31
  30m wr #0 if #0 zd    ;save data to disk

12 10m
sat, d20
  (p1 pl1 ph1):f1
  lo to sat times l20
  d1
  2u rpp9
  2u rpp8
  (p1 pl1 ph2):f1
  del25
13 del26 
  (p12 pl12 ph8^):f2
  del26
  lo to 13 times l0
  del27
  (p2  ph5):f1
  del27
14 del26
  (p12 ph9^):f2	
  del26
  lo to 14 times l0
  del28
  go=12 ph31
  30m wr #0 if #0 zd    ;save data to disk
  1m iu0                ;increment REDOR loop
  1m iu0                ;twice
  lo to 2 times nfid    ;do td1 experiments
HaltAcqu, 1m            ;jump address for protection files
exit

ph1= 0
ph2= 0 2 1 3
ph5= 0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3
ph8= 0 1 0 1 1 0 1 0
ph9= 0 1 0 1 1 0 1 0
ph31=0 2 3 1 2 0 1 3

References

Solid state NMR: AVANCE solids user manual, version 002.

 

(top)

[Contact me] - Last updated July 22, 2016
Solid-state NMR bibliography for
Aluminum-27
Antimony-121/123
Arsenic-75
Barium-135/137
Beryllium-9
Bismuth-209
Boron-11
Bromine-79/81
Calcium-43
Cesium-133
Chlorine-35/37
Chromium-53
Cobalt-59
Copper-63/65
Deuterium-2
Gallium-69/71
Germanium-73
Gold-197
Hafnium-177/179
Indium-113/115
Iodine-127
Iridium-191/193
Krypton-83
Lanthanum-139
Lithium-7
Magnesium-25
Manganese-55
Mercury-201
Molybdenum-95/97
Neon-21
Nickel-61
Niobium-93
Nitrogen-14
Osmium-189
Oxygen-17
Palladium-105
Potassium-39/41
Rhenium-185/187
Rubidium-85/87
Ruthenium-99/101
Scandium-45
Sodium-23
Strontium-87
Sulfur-33
Tantalum-181
Titanium-47/49
Vanadium-51
Xenon-131
Zinc-67
Zirconium-91



Copyright 2002- pascal-man.com. All rights reserved.