# al-zfilter-amplitude-100-cycling-p2.in
# approach: 100-phase cycling the first and the second pulses and the receiver

# spin-5/2 echo and antiecho amplitude optimization
# versus the second-pulse duration
# in three-pulse z-filtered amplitude-modulated 5Q-MAS sequence,
# the first-pulse duration p1 = 4 micro seconds
# the third-pulse duration p3 = 2 micro seconds

spinsys {
  channels 27Al
  nuclei   27Al
  quadrupole 1 2 3e6 0 0 0 0
}

par {
  spin_rate        5000
  variable tsw     0.25
  sw               1.0e6/tsw
  np               17
  crystal_file     rep10
  gamma_angles     10
  proton_frequency 800e6
  start_operator   I1z
  detect_operator  I1c
  verbose          1101
  variable rf      90000
  variable rf3     93000
  variable p1      4
  variable p3      2
  variable NA      10
  variable NB      10
  variable deltapA -5
  variable deltapB 5
}

proc pulseq {} {
  global par
  maxdt $par(tsw)

  pulse  $par(p1) $par(rf) $par(phA)
  store 10

  reset
  acq $par(phREC)       
  for {set i 1} {$i < $par(np)} {incr i} {
    reset
    prop 10
    pulse [expr ($i)*$par(tsw)] $par(rf)  $par(phB)
    pulse $par(p3)              $par(rf3) $par(phC)
    acq                     [expr $par(phREC) - 90]

  }
}

proc main {} {
  global par

  set par(phC)   0

  for {set jB 0} {$jB < $par(NB)} {incr jB} {
    set par(phB)   [expr $jB*360./$par(NB)]

    for {set jA 0} {$jA < $par(NA)} {incr jA} {
      set par(phA)   [expr $jA*360./$par(NA)]
      set par(phREC) [expr $par(deltapA)*$par(phA) + $par(deltapB)*$par(phB)]

      set g [fsimpson]
      if [info exists f] {
        fadd $f $g
        funload $g
      } else {
        set f $g
      }
    }
  }

  fsave $f $par(name).fid
  funload $f
  puts "Larmor frequency (Hz) of 27Al: "
  puts [resfreq 27Al $par(proton_frequency)]
}

# SIMP
# NP=17
# SW=4000000
# TYPE=FID
# DATA
# 0 0
# 0.00032357845 -4.61130678e-07
# 0.00900225373 -3.84968603e-05
# 0.0539979332 -0.000419631719
# 0.161713365 -0.00194394253
# 0.310843092 -0.00540028339
# 0.420356267 -0.0103971936
# 0.400809216 -0.0147703633
# 0.226169894 -0.0155538072
# -0.0431774107 -0.0111002646
# -0.307245793 -0.00284064251
# -0.498378015 0.00488941477
# -0.618464788 0.00734563169
# -0.721296989 0.00257422418
# -0.865872374 -0.00730180784
# -1.08094735 -0.0177860162
# -1.36123207 -0.0250674266
# END