# Co-7Q-referencephase196.in

# spin-7/2 anti echo and echo amplitude optimization
# versus the first-pulse duration
# in three-pulse amplitude-modulated z-filter 7QMAS,
# the second-pulse duration p2 = 4 micro seconds
# the third-pulse duration p3 = 2 micro seconds
# nested phase cycling with reference receiver phase

spinsys {
  channels 59Co
  nuclei   59Co
  quadrupole 1 2 3e6 0 0 0 0
}

par {
  spin_rate        5000
  variable tsw     0.25
  sw               1.0e6/tsw
  np               17
  crystal_file     rep10
  gamma_angles     10
  proton_frequency 800e6
  start_operator   I1z
  detect_operator  I1c
  verbose          1101
  variable rf      90000
  variable rf3     9300
  variable p2      4
  variable p3      2
  variable NA      14
  variable NB      14
  variable deltapA 7
  variable deltapB -7
}

proc pulseq {} {
  global par
  maxdt $par(tsw)

  acq -y
  for {set i 1} {$i < $par(np)} {incr i} {
    pulse $par(tsw) $par(rf)  $par(phA)
    store 2
    pulse $par(p2)  $par(rf)  $par(phB)
    pulse $par(p3)  $par(rf3) $par(phC)
    acq                 [expr $par(phREC) - 90]
    reset
    prop 2
  }
}

proc main {} {
  global par

  set par(phC)   0

  for {set jB 0} {$jB < $par(NB)} {incr jB} {
    set par(phB)   [expr $jB*360./$par(NB)]

    for {set jA 0} {$jA < $par(NA)} {incr jA} {
      set par(phA)   [expr $jA*360./$par(NA)]
      set par(phREC) [expr $par(deltapA)*$par(phA) + $par(deltapB)*$par(phB)]

      set g [fsimpson]
      if [info exists f] {
        fadd $f $g
        funload $g
      } else {
        set f $g
      }
    }
  }

  fsave $f $par(name).fid
  funload $f
  puts "Larmor frequency (Hz) of 59Co: "
  puts [resfreq 59Co $par(proton_frequency)]
}

#SIMP
#NP=17
#SW=4000000
#TYPE=FID
#DATA
#0 0
#4.19664303e-14 6.66133815e-16
#3.95004474e-10 -3.64153152e-13
#7.05223893e-08 -7.88690224e-11
#2.56584438e-06 -2.92266733e-09
#3.73516642e-05 -4.06848593e-08
#0.000293343329 -2.96187017e-07
#0.00146016698 -1.32726412e-06
#0.00507719481 -3.95985993e-06
#0.0130905876 -7.88175253e-06
#0.0257343338 -8.44108228e-06
#0.0378339947 7.12985293e-06
#0.0350744907 6.15735736e-05
#-0.00730783748 0.000185746771
#-0.12129322 0.000413230767
#-0.338161594 0.000773212367
#-0.67847274 0.0012838289
#END