# Co-5Q-referencephase100.in

# spin-7/2 anti echo and echo amplitude optimization
# versus the first-pulse duration
# in three-pulse amplitude-modulated z-filter 5QMAS,
# the second-pulse duration p2 = 4 micro seconds
# the third-pulse duration p3 = 2 micro seconds
# nested phase cycling with reference receiver phase

spinsys {
  channels 59Co
  nuclei   59Co
  quadrupole 1 2 3e6 0 0 0 0
}

par {
  spin_rate        5000
  variable tsw     0.25
  sw               1.0e6/tsw
  np               17
  crystal_file     rep10
  gamma_angles     10
  proton_frequency 800e6
  start_operator   I1z
  detect_operator  I1c
  verbose          1101
  variable rf      90000
  variable rf3     9300
  variable p2      4
  variable p3      2
  variable NA      10
  variable NB      10
  variable deltapA 5
  variable deltapB -5
}

proc pulseq {} {
  global par
  maxdt $par(tsw)

  acq -y
  for {set i 1} {$i < $par(np)} {incr i} {
    pulse $par(tsw) $par(rf)  $par(phA)
    store 2
    pulse $par(p2)  $par(rf)  $par(phB)
    pulse $par(p3)  $par(rf3) $par(phC)
    acq                 [expr $par(phREC) - 90]
    reset
    prop 2
  }
}

proc main {} {
  global par

  set par(phC)   0

  for {set jB 0} {$jB < $par(NB)} {incr jB} {
    set par(phB)   [expr $jB*360./$par(NB)]

    for {set jA 0} {$jA < $par(NA)} {incr jA} {
      set par(phA)   [expr $jA*360./$par(NA)]
      set par(phREC) [expr $par(deltapA)*$par(phA) + $par(deltapB)*$par(phB)]

      set g [fsimpson]
      if [info exists f] {
        fadd $f $g
        funload $g
      } else {
        set f $g
      }
    }
  }

  fsave $f $par(name).fid
  funload $f
  puts "Larmor frequency (Hz) of 59Co: "
  puts [resfreq 59Co $par(proton_frequency)]
}

#SIMP
#NP=17
#SW=4000000
#TYPE=FID
#DATA
#0 0
#3.48981089e-08 -2.32251955e-11
#1.67226128e-05 -1.10760917e-08
#0.000554365041 -3.15535262e-07
#0.00592292417 -2.6888699e-06
#0.0331406931 -1.13329633e-05
#0.120726708 -3.0331844e-05
#0.322485678 -6.34993105e-05
#0.682010458 -0.000130756344
#1.20912731 -0.000293035173
#1.88205793 -0.000640162313
#2.66936196 -0.00121183584
#3.5440753 -0.00190606434
#4.47155025 -0.00247478643
#5.37870778 -0.00262993604
#6.13747993 -0.00217551952
#6.59301014 -0.00107303925
#END