z-filter 5QMAS pulse program for spins 5/2, 7/2, and 9/2
Contributor: Y. Millot




Home and Applets > Pulse Program > XwinNMR 3.5 > Avance NMR Spectrometer

Below NMR pulse program describes the z-filter 5QMAS (1D and 2D) experiment with cogwheel phase cycling or nested phase cycling applied to nuclei with 5/2, 7/2, or 9/2 spins.

This NMR pulse program is for Bruker Avance spectrometers.

A pure absorption 2D spectrum is obtained with the shearing transformation.

Code for Avance NMR spectrometers

; 5qzfilter.ym (XWIN-NMR 3.0)
; 01072009

;5Q MAS pulse program for half integer spin nuclei
;ZGOPTNS (zg-options) are:
;  -DQQS5Cog ... for I=5/2 (ns=60)  Cog60(0,6,17,47)  = Cog60(28,34,45,15)
;  -DQQS7Cog ... for I=7/2 (ns=80)  Cog80(0,8,1,41)   = Cog80(59,67,60,20)
;  -DQQS9Cog ... for I=9/2 (ns=100) Cog100(0,10,1,51) = Cog100(74,84,75,25)
;  -DQQS5Nesdig .for I=5/2 (ns=60)  nested phase cycling with digital receiver
;  -DQQS7Nesdig .for I=7/2 (ns=80)  nested phase cycling with digital receiver
;  -DQQS579Nes ..for I=5/2, 7/2 or 9/2 
;                          (ns=100) nested phase cycling with standard receiver

;d1 : recycle delay
;p1 : excitation pulse at pl11
;p2 : conversion pulse at pl11
;p3 : 90 degree selective pulse at pl13
;pl1 : =120 dB
;pl11 : power level for excitation and conversion pulses
;pl13 : power level for selective pulse
;d4 : =20u, delay for z-filter 
;d0 : =3u
;in0 : 1 rotation period for synchronised experiment
;td1 : number of t1-experiments
;FnMODE : States or TPPI
;Shearing use AU program xfshear (FnMode = States) 
;ph30 ph31:r for receiver phase <> kpi/2

  ze                  ; clear memory, new data replace old data,
                      ; switch AD converter to replace mode,
                      ; perform DS before next acquisition,

1 d1                  ; recycle delay,
  10u pl11:f1         ; 10 microsecond delay,
                      ; set high power in f1 channel,
  (p1 ph1):f1         ; high-power excitation pulse,
  d0                  ; delay between pulses, t1 increment,
  (p2 ph2):f1         ; high-power conversion pulse,
  d4  pl13:f1         ; set low power in f1 channel,
  (p3 ph3):f1         ; low-power 90 pulse,
#ifdef QQS5Nesdig
  go=1 ph30 ph31:r    ; instruction must be in that order
                      ; signal acquisition,
                      ; loop to 1, ns times for averaging,
#else
#ifdef QQS7Nesdig
  go=1 ph30 ph31:r    ; instruction must be in that order
                      ; signal acquisition,
                      ; loop to 1, ns times for averaging,
#else
  go=1 ph31           ; signal acquisition,
                      ; loop to 1, ns times for averaging,
#endif
#endif
  d1 mc #0 to 1 F1PH(ip1, id0)
                      ; delay for disk I/O, store signal,
                      ; increase FID number,
                      ; delete memory data,
                      ; increment p1 pulse phase by 360/20 
                      ; for States procedure,
                      ; increment time d0 by in0,
  exit                ; end of the pulse program

#ifdef QQS5Cog
 ph10= (60) 0  1  2  3  4  5  6  7  8  9 
           10 11 12 13 14 15 16 17 18 19 
           20 21 22 23 24 25 26 27 28 29 
           30 31 32 33 34 35 36 37 38 39
           40 41 42 43 44 45 46 47 48 49 
           50 51 52 53 54 55 56 57 58 59
 ph1 = (20) ph10*28   ; excitation pulse phase
 ph2 =      ph10*34   ; conversion pulse phase
 ph3 =      ph10*45   ; 90 selective pulse phase
 ph31=      ph10*15   ; receiver phase : (360/60)*15*m=90*m
#else
#ifdef QQS7Cog
 ph10= (80) 0  1  2  3  4  5  6  7  8  9 
           10 11 12 13 14 15 16 17 18 19 
           20 21 22 23 24 25 26 27 28 29 
           30 31 32 33 34 35 36 37 38 39 
           40 41 42 43 44 45 46 47 48 49 
           50 51 52 53 54 55 56 57 58 59 
           60 61 62 63 64 65 66 67 68 69 
           70 71 72 73 74 75 76 77 78 79
 ph1 = (20) ph10*59   ; excitation pulse phase
 ph2 =      ph10*67   ; conversion pulse phase
 ph3 =      ph10*60   ; 90 selective pulse phase
 ph31=      ph10*20   ; receiver phase : (360/80)*20*m=90*m
#else
#ifdef QQS9Cog
 ph10= (100) 0  1  2  3  4  5  6  7  8  9 
            10 11 12 13 14 15 16 17 18 19 
            20 21 22 23 24 25 26 27 28 29 
            30 31 32 33 34 35 36 37 38 39 
            40 41 42 43 44 45 46 47 48 49 
            50 51 52 53 54 55 56 57 58 59 
            60 61 62 63 64 65 66 67 68 69 
            70 71 72 73 74 75 76 77 78 79 
            80 81 82 83 84 85 86 87 88 89 
            90 91 92 93 94 95 96 97 98 99
 ph1 = (20) ph10*74   ; excitation pulse phase
 ph2 =      ph10*84   ; conversion pulse phase
 ph3 =      ph10*75   ; 90 selective pulse phase
 ph31=      ph10*25   ; receiver phase : (360/100)*25*m=90*m
#else 
#ifdef QQS5Nesdig
 ph1 = (20) 0 2 4 6 8 10 12 14 16 18
 ph2 =      0
 ph3 = (6) {0}*10 {1}*10 {2}*10 {3}*10 {4}*10 {5}*10
 ph30=      ph1*5 + ph3
 ph31=      0
#else 
#ifdef QQS7Nesdig
 ph1 = (20) 0 2 4 6 8 10 12 14 16 18
 ph2 =      0
 ph3 = (8) {0}*10 {1}*10 {2}*10 {3}*10 {4}*10 {5}*10 {6}*10 {7}*10
 ph30=      ph1*5 + ph3
 ph31=      0
#else
#ifdef QQS579Nes
 ph1 = (20)  0 2 4 6 8 10 12 14 16 18
 ph2 = (10) {0}*10 {1}*10 {2}*10 {3}*10 {4}*10 {5}*10 {6}*10 {7}*10 {8}*10 {9}*10
 ph3 =       0
 ph31=       ph1*5 - ph2*5
#endif
#endif
#endif
#endif
#endif
#endif
  

This pulse program remains valid for the third pulse with strong amplitude for better excitation of off-resonance nuclei.

(top)

[Contact me] - Last updated December 16, 2012
Solid-state NMR bibliography for
Aluminum-27
Antimony-121/123
Arsenic-75
Barium-135/137
Beryllium-9
Bismuth-209
Boron-11
Bromine-79/81
Calcium-43
Cesium-133
Chlorine-35/37
Chromium-53
Cobalt-59
Copper-63/65
Deuterium-2
Gallium-69/71
Germanium-73
Gold-197
Hafnium-177/179
Indium-113/115
Iodine-127
Iridium-191/193
Krypton-83
Lanthanum-139
Lithium-7
Magnesium-25
Manganese-55
Mercury-201
Molybdenum-95/97
Neon-21
Nickel-61
Niobium-93
Nitrogen-14
Osmium-189
Oxygen-17
Palladium-105
Potassium-39/41
Rhenium-185/187
Rubidium-85/87
Ruthenium-99/101
Scandium-45
Sodium-23
Strontium-87
Sulfur-33
Tantalum-181
Titanium-47/49
Vanadium-51
Xenon-131
Zinc-67
Zirconium-91



Copyright 2002- pascal-man.com. All rights reserved.