# Al-5Q-referencephase100.in

# spin-5/2 anti echo and echo amplitude optimization
# versus the first-pulse duration
# in three-pulse amplitude-modulated z-filter 5QMAS,
# the second-pulse duration p2 = 4 micro seconds
# the third-pulse duration p3 = 2 micro seconds
# nested phase cycling with reference receiver phase

spinsys {
  channels 27Al
  nuclei   27Al
  quadrupole 1 2 3e6 0 0 0 0
}

par {
  spin_rate        5000
  variable tsw     0.25
  sw               1.0e6/tsw
  np               17
  crystal_file     rep10
  gamma_angles     10
  proton_frequency 800e6
  start_operator   I1z
  detect_operator  I1c
  verbose          1101
  variable rf      90000
  variable rf3     9300
  variable p2      4
  variable p3      2
  variable NA      10
  variable NB      10
  variable deltapA 5
  variable deltapB -5
}

proc pulseq {} {
  global par
  maxdt $par(tsw)

  acq -y
  for {set i 1} {$i < $par(np)} {incr i} {
    pulse $par(tsw) $par(rf)  $par(phA)
    store 2
    pulse $par(p2)  $par(rf)  $par(phB)
    pulse $par(p3)  $par(rf3) $par(phC)
    acq                 [expr $par(phREC) - 90]
    reset
    prop 2
  }
}

proc main {} {
  global par

  set par(phC)   0

  for {set jB 0} {$jB < $par(NB)} {incr jB} {
    set par(phB)   [expr $jB*360./$par(NB)]

    for {set jA 0} {$jA < $par(NA)} {incr jA} {
      set par(phA)   [expr $jA*360./$par(NA)]
      set par(phREC) [expr $par(deltapA)*$par(phA) + $par(deltapB)*$par(phB)]

      set g [fsimpson]
      if [info exists f] {
        fadd $f $g
        funload $g
      } else {
        set f $g
      }
    }
  }

  fsave $f $par(name).fid
  funload $f
  puts "Larmor frequency (Hz) of 27Al: "
  puts [resfreq 27Al $par(proton_frequency)]
}

#SIMP
#NP=17
#SW=4000000
#TYPE=FID
#DATA
#0 0
#-2.12986608e-09 1.3486748e-12
#-9.7577097e-07 6.19650802e-10
#-3.12143846e-05 1.9826762e-08
#-0.000326039105 2.07804877e-07
#-0.00181331962 1.18744633e-06
#-0.00668640961 4.71373012e-06
#-0.0183851674 1.48649096e-05
#-0.0405853665 4.0173717e-05
#-0.0760261106 9.66432271e-05
#-0.126658022 0.000209650833
#-0.195158579 0.000410629174
#-0.285864452 0.000726230971
#-0.403250007 0.0011640517
#-0.548253895 0.00170349741
#-0.714861922 0.0022977669
#-0.889420393 0.00288578236
#END